TEXT » @..HPDFPRINT:

 

This command is used to render a single line of text data in the specified font, size, color and alignment at the specified row and column. The text rendered is left aligned unless otherwise specified. Only following Base14 fonts are built-in. Courier, Courier-Bold, Courier-Oblique, Courier-BoldOblique, Helvetica, Helvetica-Bold, Helvetica-Oblique, Helvetica-BoldOblique, Times-Roman, Times-Bold, Times-Italic, Times-BoldItalic, Symbol, ZapfDingbats. The text will be rendered in the current character encoding.

 

Helvetica is the default font if no fontname is specified. Default fontsize is 12.

 

True Type Fonts can also be used if the absolute address of the True Type Font file is mentioned.

 

Otherwise the TTF shall be required at the runtime in the same directory as of the executable file.

 

Syntax:

 

@ Row , Col HPDFPRINT cText ;

[ FONT cFontName ] ;

[ SIZE nFontSize ] ;

[ COLOR aColor ] ;

[ CENTER|RIGHT ]

 

Source code example:

 

@ 205, 10 HPDFPRINT "This is a sample Text in default font."

@ 220, 10 HPDFPRINT "This is a sample Text in Times-Roman font." FONT "Times-Roman" SIZE 14

@ 235, 200 HPDFPRINT "This is right aligned text" FONT "Courier-Bold" SIZE 14 RIGHT

@ 250, 105 HPDFPRINT "This is center aligned text" COLOR { 255, 0, 0 } CENTER

@ 270, 105 HPDFPRINT "This is text in bigger font size" SIZE 30 COLOR { 255, 0, 0 }

@ 290, 10 HPDFPRINT "The font is Tscparan.TTF" FONT "Tscparan.TTF" size 12

 

Print sample:

 

 

 

 

TEXT » @..HPDFPRINT..TO:

 

This command is just like the previous command @..HPDFPRINT. However, this command is used to print the text data in multiline. The text will be rendered inside a rectangular area specified in the command. The text can be aligned in JUSTIFY alignment also. All other options are just the same as the previous command.

 

Syntax:

 

@ Row , Col HPDFPRINT cText ;

TO ToRow, ToCol ;

[ FONT cFontName ] ;

[ SIZE nFontSize ] ;

[ COLOR aColor ] ;

[ CENTER|RIGHT ]

 

Source code example:

 

@ 230, 10 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area left aligned." to 250, 60

@ 230, 80 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area right aligned." to 250, 130 RIGHT

@ 230, 150 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area justified." to 250, 200 JUSTIFY

@ 255, 10 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area justified." to 275, 60 JUSTIFY 

 

Print sample:

 

 

 

 

TEXT » SET HPDFPAGE LINESPACING:

 

This command is used to change the default line spacing in @..HPDFPRINT..TO command.

 

Syntax:

 

SET HPDFPAGE LINESPACING TO nSpacing

 

Source code example:

 

@ 230, 10 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area left aligned." to 250, 60

SET HPDFPAGE LINESPACING TO 6

@ 230, 70 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area left aligned with a different linespacing." to 260, 120

SET HPDFPAGE LINESPACING TO 0

@ 230, 130 HPDFPRINT "This is a small paragraph to be printed inside a rectangular area left aligned line spacing back to normal." to 230, 180

 

Print sample:

 

 

 

 

GRAPHICS » @..HPDFPRINT LINE TO:

 

This command is used to draw a continuous line from the specified location to a specified another location.

Color and width of the line can be specified optionally. The default color is black.

 

Syntax:

 

@ Row , Col HPDFPRINT LINE ;

TO ToRow, ToCol ;

[ PENWIDTH nWidth ] ;

[ COLOR aColor ] ;

 

Source code example:

 

@ 230, 10 HPDFPRINT LINE TO 230, 50

@ 235, 10 HPDFPRINT LINE TO 235, 50 PENWIDTH 1 COLOR { 255, 0, 0 }

@ 230, 70 HPDFPRINT LINE TO 250, 70 PENWIDTH 1 COLOR { 255, 0, 0 }

@ 230, 100 HPDFPRINT LINE TO 250, 150 PENWIDTH 2 COLOR { 255, 0, 255 } 

 

Print sample:

 

 

 

 

GRAPHICS » @..HPDFPRINT RECTANGLE TO:

 

This command is used to draw a rectangle from the specified location to a specified another location. Color and width of the line can be specified optionally. The default color is black. The rectangle can be filled. Rounded clause will draw a rounded rectangle. Optionally Curve length can also be specified for Rounded rectangle.

 

Syntax:

 

@ Row , Col HPDFPRINT RECTANGLE ;

TO ToRow, ToCol ;

[ PENWIDTH nWidth ] ;

[ COLOR aColor ] ;

[ FILLED ];

ROUNDED ;

[ CURVE nCurve ]

 

Source code example:

 

@ 230, 10 HPDFPRINT RECTANGLE TO 250, 50

@ 230, 60 HPDFPRINT RECTANGLE TO 250, 100 PENWIDTH 1 COLOR { 255, 0, 0 }

@ 230, 110 HPDFPRINT RECTANGLE TO 250, 150 PENWIDTH 1 COLOR { 255, 0, 0 } FILLED

@ 260, 10 HPDFPRINT RECTANGLE TO 280, 50 PENWIDTH 2 COLOR { 255, 0, 255 } ROUNDED

@ 260, 60 HPDFPRINT RECTANGLE TO 280, 150 PENWIDTH 2 COLOR { 255, 0, 255 } ROUNDED CURVE 10

@ 260, 160 HPDFPRINT RECTANGLE TO 280, 200 PENWIDTH 2 COLOR { 255, 255, 0 } FILLED ROUNDED CURVE 10

 

Print sample:

 

 

 

 

GRAPHICS » @..HPDFPRINT CIRCLE:

 

This command is used to draw a circle with the given radius having row and col as the center.

Color and width of the line can be specified optionally. The default color is black. The circle can be filled.

 

Syntax:

 

@ Row , Col HPDFPRINT CIRCLE RADIUS nRadius ;

[ PENWIDTH nWidth ] ;

[ COLOR aColor ] ;

[ FILLED ]

 

Source code example:

 

@ 230, 40 HPDFPRINT CIRCLE RADIUS 10

@ 230, 80 HPDFPRINT CIRCLE RADIUS 10 PENWIDTH 2

@ 230, 120 HPDFPRINT CIRCLE RADIUS 10 PENWIDTH 2 COLOR { 0, 0, 255 }

@ 230, 160 HPDFPRINT CIRCLE RADIUS 10 COLOR { 0, 0, 255 } FILLED

 

Print sample:

 

 

 

GRAPHICS » @..HPDFPRINT ELLIPSE:

 

This command is used to draw an ellipse with the given horizontal radius and vertical radius having row and col as the center. Color and width of the line can be specified optionally. The default color is black. The ellipse can be filled.

 

Syntax:

 

@ Row , Col HPDFPRINT ELLIPSE HORIZONTAL RADIUS nHRadius ;

VERTICAL RADIUS nVRadius ;

[ PENWIDTH nWidth ] ;

[ COLOR aColor ] ;

[ FILLED ]

 

Source code example:

 

@ 230, 40 HPDFPRINT ELLIPSE HORIZONTAL RADIUS 20 VERTICAL RADIUS 10

@ 240, 80 HPDFPRINT ELLIPSE HORIZONTAL RADIUS 10 VERTICAL RADIUS 20 PENWIDTH 2

@ 230, 120 HPDFPRINT ELLIPSE HORIZONTAL RADIUS 20 VERTICAL RADIUS 10 PENWIDTH 2 COLOR { 0, 0, 255 }

@ 240, 160 HPDFPRINT ELLIPSE HORIZONTAL RADIUS 10 VERTICAL RADIUS 20 COLOR { 0, 0, 255 } FILLED

 

Print sample:

 

 

 

GRAPHICS » @..HPDFPRINT ARC:

 

This command is used to draw an arc with given radius from given angle to given another angle.

Color and width of the line can be specified optionally. The default color is black.

 

Syntax:

 

@ Row , Col HPDFPRINT ARC RADIUS nRadius ;

ANGLE FROM nFromAngle ;

TO nToAngle ;

[ PENWIDTH nWidth ] ;

[ COLOR aColor ]

 

Source code example:

 

@ 230, 40 HPDFPRINT ARC RADIUS 10 ANGLE FROM 0 TO 180

@ 230, 80 HPDFPRINT ARC RADIUS 10 ANGLE FROM 90 TO 270 PENWIDTH 2

@ 230, 120 HPDFPRINT ARC RADIUS 10 ANGLE FROM 30 TO 200 PENWIDTH 2 COLOR { 0, 100, 100 }

 

Print sample:

 

 

 

GRAPHICS » @..HPDFPRINT CURVE:

 

This command is used to draw a Bézier curve from a point taking second point as curvature to the third point. Color and width of the line can be specified optionally. The default color is black.

 

Syntax:

 

@ Row , Col HPDFPRINT CURVE ;

FROM FromRow, FromCol ;

TO ToRow, ToCol ;

[ PENWIDTH nWidth ] ;

[ COLOR aColor ]

 

Source code example:

 

@ 230, 40 HPDFPRINT CURVE FROM 230, 10 TO 250, 30

@ 230, 80 HPDFPRINT CURVE FROM 230, 100 TO 250, 60 PENWIDTH 2

@ 230, 120 HPDFPRINT CURVE FROM 230, 160 TO 250, 120 PENWIDTH 2 COLOR { 100, 0, 200 }

 

Print sample:

 

 

 

@..HPDFPRINT IMAGE:

 

This command is used to insert a PNG/JPG format image file from the resource or the given path inside the document at the current location. The image will be stretched according to the given width and length. Specify image type 1 for PNG and 2 for JPG.

 

Syntax:

 

@ Row , Col HPDFPRINT IMAGE cImage ;

WIDTH nWidth ;

LENGTH nLength

TYPE JPG|PNG

 

Source code example:

 

@ 230, 10 HPDFPRINT IMAGE "hmghpdf.png" TYPE PNG width 100 height 30

@ 230, 110 HPDFPRINT IMAGE "imgpng" TYPE PNG width 40 height 40

@ 230, 160 HPDFPRINT IMAGE "imgjpg" TYPE JPG width 40 height 40

 

Print sample:

 

 

 

@..HPDFTOOLTIP:

 

This command is used to insert a tooltip at the specified place with the specified icon. When the user hovers the mouse over this icon, the tooltip will be displayed.

 

Syntax:

 

@ Row , Col HPDFPRINT TOOLTIP cToolTip ;

ICON COMMENT|KEY|NOTE|HELP|

NEW_PARAGRAPH|PARAGRAPH|INSERT

 

Source code example:

 

@ 240, 10 HPDFTOOLTIP "Comment Tooltip" ICON COMMENT

@ 250, 10 HPDFTOOLTIP "Key Tooltip" ICON KEY

@ 260, 10 HPDFTOOLTIP "Note Tooltip" ICON NOTE

@ 240, 50 HPDFTOOLTIP "Help Tooltip" ICON HELP

@ 250, 50 HPDFTOOLTIP "New_Paragraph Tooltip" ICON NEW_PARAGRAPH

@ 260, 50 HPDFTOOLTIP "Paragraph Tooltip" ICON PARAGRAPH

@ 240, 90 HPDFTOOLTIP "Insert Tooltip" ICON INSERT

 

Screen Shot:

 

 

 

@..HPDFPAGELINK:

 

This command is used to link a particular page to the specified text. Font, size, color, alignment options are the same as text data. A BORDER around the link can also be drawn with the optional width parameter.

 

Syntax:

 

@ Row, Col HPDFPAGELINK cLink TO nPage ;

[ FONT cFontName ] ;

[ SIZE nFontSize ] ;

[ COLOR aColor ] ;

[ CENTER|RIGHT ] ;

[ BORDER ];

[ WIDTH nwidth ]

 

Source code example:

 

@ 230, 10 HPDFPAGELINK "Go to Page 5" TO 5

@ 230, 70 HPDFPAGELINK "Go to Page 8" TO 8 FONT "Courier" size 18 color { 255, 0, 0 }

@ 230, 130 HPDFPAGELINK "Go to Page 10" TO 10 color { 255, 0, 0 } BORDER

@ 250, 10 HPDFPAGELINK "Go to Page 12" TO 12 color { 0, 0, 255 } BORDER WIDTH 1

 

Screen Shot:

 

 

 

@..HPDFURLLINK:

 

This command is used to link a particular Web URL/E-Mail ID to the specified text. Font, size, color, alignment options are the same as text data.

 

Syntax:

 

@ Row, Col HPDFURLLINK cLink TO nPage ;

[ FONT cFontName ] ;

[ SIZE nFontSize ] ;

[ COLOR aColor ] ;

[ CENTER|RIGHT ]

 

Source code example:

 

@ 230, 10 HPDFURLLINK "HMGFORUM" TO "http://www.hmgforum.com" color { 0, 0, 255 }

@ 240, 10 HPDFURLLINK "Mail me" TO "mailto:srgiri@dataone.in" color { 0, 0, 255 }

 

Screen Shot:

 

 

 

Tips:

 

If you find same problem of security block like this:

 

 

You will find at this forum this topic with further discussion about it in:

 

http://www.hmgforum.com/viewtopic.php?p=22062#p22062